展开生成树

从起始节点开始，遵循关系并遵守标签过滤器，将可达的生成树扩展到最大级别。返回的路径集合共同构成一个生成树。

此过程的行为与 带配置展开路径 相同，配置为 uniqueness: "NODE_GLOBAL"。

过程概览

该过程描述如下

限定名称 类型

apoc.path.spanningTree
apoc.path.spanningTree(startNode ANY, config MAP<STRING, ANY>) - 返回从起始 NODE 按照给定 RELATIONSHIP 类型扩展到最大深度的生成树 PATH 值。

过程

配置参数

过程支持以下配置参数

表 1. 配置参数
名称 类型 默认值 描述

minLevel

整数

-1

遍历中的最小跳数。如果指定，必须为 0 或 1

maxLevel

整数

-1

遍历中的最大跳数

relationshipFilter

字符串

空

要遍历的关系类型和方向。

请参阅关系过滤器。

labelFilter

字符串

空

要遍历的节点标签。

请参阅标签过滤器。

beginSequenceAtStart

布尔值

true

从起始节点的一个节点之外开始匹配节点标签和/或关系类型的序列（在 relationshipFilter、labelFilter 或 sequences 中定义）。

bfs

布尔值

true

遍历时使用广度优先搜索。如果设置为 false，则使用深度优先搜索

filterStartNode

布尔值

false

labelFilter 和 sequence 是否适用于扩展的起始节点。

limit

整数

-1

限制返回的路径数量。当使用 bfs:true 时，这将返回到终止或结束节点过滤器中带有标签的 n 个最近节点的路径，其中 n 是给定的限制。如果设置为 true，则当扩展通常因无结果而消除行时，会产生 null 值。

endNodes

节点列表

空

只有这些节点可以结束返回的路径，并且如果可能，扩展将继续越过这些节点。

terminatorNodes

节点列表

空

只有这些节点可以结束返回的路径，并且扩展不会越过这些节点。

allowlistNodes

节点列表

空

只有这些节点被允许在扩展中（如果存在，endNodes 和 terminatorNodes 也将被允许）。

denylistNodes

节点列表

空

返回的路径都不会包含这些节点。

whitelistNodes (已弃用)

节点列表

空

请参阅 allowlistNodes。

blacklistNodes (已弃用)

节点列表

空

请参阅 denylistNodes。

它还具有以下固定参数

表 2. 配置参数
名称 类型 默认值 描述

uniqueness

字符串

NODE_GLOBAL

遍历中扩展关系时使用的策略。NODE_GLOBAL 意味着一个节点不能被遍历多次。这是传统遍历框架所做的事情。

关系过滤器

关系过滤器的语法描述如下

语法: [<]RELATIONSHIP_TYPE1[>]|[<]RELATIONSHIP_TYPE2[>]|…​

输入 类型 方向

LIKES>

LIKES

出站

<FOLLOWS

FOLLOWS

入站

KNOWS

KNOWS

双向

>

任意类型

出站

<

任意类型

入站

标签过滤器

标签过滤器的语法描述如下

语法: [+-/>]LABEL1|LABEL2|*|…​

符号 过滤器类型 输入示例 描述

-

黑名单

-Foe

路径中没有节点会包含黑名单中的标签。

+

白名单

+Friend

路径中的所有节点必须具有白名单中的标签（如果使用终止节点和结束节点过滤器，则这些节点除外）。如果没有白名单运算符，则允许所有标签。

/

终止

/Friend

仅返回到达具有给定标签的节点的路径，并停止超出该节点的进一步扩展。终止节点不必遵守白名单。终止过滤优先于结束节点过滤。

>

结束节点

>Friend

仅返回到达具有给定标签的节点的路径，但继续扩展以匹配其后的结束节点。结束节点不必遵守白名单即可返回，但只有当节点具有白名单中的标签时，才允许超出它们进行扩展。

:

复合标签

Foe:Friend

这返回标签的合取，例如 /Foo:Bar 表示终止节点必须同时匹配 Foo 和 Bar。要在标签中包含没有特殊含义的 :，请使用 \ 进行转义，例如 Foo\:Bar 是标签 Foo:Bar。

标签过滤器运算符的优先级和行为

可以同时使用多个标签过滤器运算符。以下示例：

labelFilter:'+Person|Movie|-SciFi|>Western|/Romance'

如果我们分析这个标签过滤器，可以看到：

  • :Person 和 :Movie 标签被列入白名单

  • :SciFi 被列入黑名单

  • :Western 是一个结束节点标签

  • :Romance 是一个终止标签。

运算符评估的优先级不取决于它们在 labelFilter 中的位置，而是固定的。

黑名单过滤器 -，终止过滤器 /，结束节点过滤器 >，白名单过滤器 +。

这意味着

  • 返回路径的节点中永远不会出现黑名单标签 -，即使相同的标签（或具有黑名单标签的节点的另一个标签）包含在另一个过滤列表中。

  • 如果使用终止过滤器 / 或结束节点过滤器 >，则仅返回到带有这些标签的节点的路径作为结果。这些结束节点不受白名单过滤器的限制。

  • 如果一个节点是终止节点 /，则不会在该节点之外进行进一步扩展。

  • 白名单仅适用于从终止或结束节点过滤器返回的节点（但不包括这些结束节点）。如果没有结束节点或终止节点运算符，则白名单适用于路径中的所有节点。

  • 如果 labelFilter 中没有白名单运算符，则视为所有标签都已列入白名单。

示例

本节中的示例基于以下示例图

MERGE (mark:Person:DevRel {name: "Mark"})
MERGE (lju:Person:DevRel {name: "Lju"})
MERGE (praveena:Person:Engineering {name: "Praveena"})
MERGE (zhen:Person:Engineering {name: "Zhen"})
MERGE (martin:Person:Engineering {name: "Martin"})
MERGE (joe:Person:Field {name: "Joe"})
MERGE (stefan:Person:Field {name: "Stefan"})
MERGE (alicia:Person:Product {name: "Alicia"})
MERGE (jake:Person:Product {name: "Jake"})
MERGE (john:Person:Product {name: "John"})
MERGE (jonny:Person:Sales {name: "Jonny"})
MERGE (anthony:Person:Sales {name: "Anthony"})
MERGE (rik:Person:Sales {name: "Rik"})

MERGE (zhen)-[:KNOWS]-(stefan)
MERGE (zhen)-[:KNOWS]-(lju)
MERGE (zhen)-[:KNOWS]-(praveena)
MERGE (zhen)-[:KNOWS]-(martin)
MERGE (mark)-[:KNOWS]-(jake)
MERGE (alicia)-[:KNOWS]-(jake)
MERGE (jonny)-[:KNOWS]-(anthony)
MERGE (john)-[:KNOWS]-(rik)

MERGE (alicia)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (joe)-[:FOLLOWS]->(praveena)
MERGE (joe)-[:FOLLOWS]->(zhen)
MERGE (mark)-[:FOLLOWS]->(stefan)
MERGE (stefan)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)
MERGE (lju)-[:FOLLOWS]->(jake)
MERGE (alicia)-[:FOLLOWS]->(jonny)
MERGE (zhen)-[:FOLLOWS]->(john)
MERGE (anthony)-[:FOLLOWS]->(joe)

下面的 Neo4j Browser 可视化显示了示例图

apoc.path.expandConfig
图 1. 示例图

KNOWS 关系类型被认为是双向的，即如果 Zhen 认识 Stefan，我们可以推断 Stefan 认识 Zhen。当使用 KNOWS 关系时，我们将忽略方向。

FOLLOWS 关系有方向，因此在使用时我们会指定方向。

关系类型和节点标签过滤器

我们从 Praveena 节点开始扩展路径。我们只希望考虑 KNOWS 关系类型，因此我们将它指定为 relationshipFilter 参数。

以下查询返回从 Praveena 开始，遍历 KNOWS 关系类型 1 到 2 跳的生成树
MATCH (p:Person {name: "Praveena"})
CALL apoc.path.spanningTree(p, {
	relationshipFilter: "KNOWS",
    minLevel: 1,
    maxLevel: 2
})
YIELD path
RETURN path;

我们可以在从 Praveena 开始的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.praveena
图 2. 从 Praveena 开始的生成树

生成树中除了 Praveena 之外还有 4 个节点。Praveena 只与 Zhen 有直接的 KNOWS 关系，但 Zhen 与另外 3 个人有 KNOWS 关系，这意味着他们也包含在生成树中。

我们还可以提供节点标签过滤器来限制返回的节点。如果只想返回路径中每个节点都带有 Engineering 标签的路径，我们将向 labelFilter 参数提供值 +Engineering。

以下查询返回从 Praveena 开始，遍历 KNOWS 关系类型 1 到 2 跳的生成树，仅包含 Engineering 节点
MATCH (p:Person {name: "Praveena"})
CALL apoc.path.spanningTree(p, {
	relationshipFilter: "KNOWS",
	labelFilter: "+Engineering",
    minLevel: 1,
    maxLevel: 2
})
YIELD path
RETURN path;

我们可以在从 Praveena 到 Engineering 节点的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.praveena eng
图 3. 从 Praveena 到 Engineering 节点的生成树

我们从生成树中失去了 Lju 和 Stefan，因为这两个节点都没有 Engineering 标签。

我们可以指定多种关系类型。以下查询从 Alicia 节点开始，然后扩展 FOLLOWS 和 KNOWS 关系

以下查询返回从 Alicia 开始，遍历 FOLLOWS 或 KNOWS 关系类型 1 到 3 跳的生成树
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.alicia
图 4. 从 Alicia 开始的生成树

此查询返回了图中 12 个人中 11 个人的路径，这表明 Alicia 连接非常广泛。

我们还可以使用标签过滤器指定遍历终止条件。如果希望遍历在遇到包含 Engineering 标签的节点时立即终止，可以使用 /Engineering 节点过滤器。

以下查询返回从 Alicia 开始，遍历 FOLLOWS 或 KNOWS 关系类型 1 到 3 跳的生成树，一旦到达带有 Engineering 标签的节点即终止
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    labelFilter: "/Engineering",
    minLevel: 1,
    maxLevel: 3
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始，在 Engineering 节点处终止的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.alicia eng
图 5. 从 Alicia 开始，在 Engineering 节点处终止的生成树

我们的生成树已缩小到除了 Alicia 之外只有 3 个其他节点。但是此查询没有捕获从 Alicia 开始包含带有 Engineering 标签的节点的完整生成树。我们可以使用 >Engineering 节点过滤器来定义一个遍历，该遍历会

  • 仅返回在具有 Engineering 标签的节点处终止的路径

  • 之后继续扩展到结束节点，寻找更多以 Engineering 标签结尾的路径

以下查询返回从 Alicia 开始，遍历 FOLLOWS 或 KNOWS 关系类型 1 到 3 跳的生成树，其中路径以带有 Engineering 标签的节点结束
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    labelFilter: ">Engineering",
    minLevel: 1,
    maxLevel: 3
})
YIELD path
RETURN path;

我们可以在从 Alicia 到 Engineering 节点的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.alicia eng end
图 6. 从 Alicia 到 Engineering 节点的生成树

现在，生成树也通过 Zhen 的关系到达 Martin。

终止节点和结束节点

除了为遍历指定终止标签和结束标签外，我们还可以指定终止节点和结束节点。

让我们基于之前找到 Alicia KNOWS 或 FOLLOWS 的人的查询。我们希望返回的生成树在到达 Mark、Joe、Zhen 或 Praveena 节点时立即停止。我们可以通过将这些节点传递给 terminatorNodes 参数来实现。

以下查询返回 Alicia FOLLOWS 或 KNOWS 的人，从 1 到 3 跳的生成树，一旦到达 Mark、Joe、Zhen 或 Rik 节点即终止
MATCH (p:Person {name: "Alicia"})
MATCH (terminator:Person)
WHERE terminator.name IN ["Mark", "Joe", "Zhen", "Rik"]
WITH p, collect(terminator) AS terminatorNodes
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    terminatorNodes: terminatorNodes
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始，在 Mark、Joe、Zhen 或 Rik 处终止的生成树中看到该生成树的 Neo4j Browser 可视化。

apoc.path.subtree.alicia terminator
图 7. 从 Alicia 开始，在 Mark、Joe、Zhen 或 Rik 处终止的生成树

Mark 和 Joe 包含在生成树中，但 Rik 和 Zhen 无法到达。这可能是因为没有不经过 Mark 和 Joe 的路径到达 Zhen 和 Rik，或者这意味着根据其他遍历条件没有路径。

我们可以通过将这些节点传递给 endNodes 参数来找出 Mark、Joe、Zhen 或 Rik 是否可达。

以下查询返回 Alicia FOLLOWS 或 KNOWS 的人，从 1 到 3 跳的生成树，一旦到达 Mark、Joe、Zhen 或 Rik 节点即结束
MATCH (p:Person {name: "Alicia"})
MATCH (end:Person)
WHERE end.name IN ["Mark", "Joe", "Zhen", "Rik"]
WITH p, collect(end) AS endNodes
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    endNodes: endNodes
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始，在 Mark、Joe、Zhen 或 Rik 处结束的生成树中看到返回的生成树的 Neo4j Browser 可视化。

apoc.path.subtree.alicia end
图 8. 从 Alicia 开始，在 Mark、Joe、Zhen 或 Rik 处结束的生成树

我们的生成树现在包含了 Joe、Mark 和 Zhen，但 Rik 仍然无法到达。

白名单节点和黑名单节点

也可以指定白名单节点和黑名单节点。

让我们基于之前找到 Alicia KNOWS 或 FOLLOWS 的人的查询。我们希望任何返回的路径只包含 Mark、Joe、Zhen 和 Praveena 节点，我们可以通过将这些节点传递给 allowlistNodes 参数来实现。

以下查询返回从 Alicia 开始，通过 FOLLOWS 或 KNOWS 关系类型可达的 1 到 3 跳的生成树，其中到达这些节点的路径必须只包含 Mark、Jonny 或 Zhen
MATCH (p:Person {name: "Alicia"})
MATCH (allowlist:Person)
WHERE allowlist.name IN ["Jonny", "Mark", "Zhen"]
WITH p, collect(allowlist) AS allowlistNodes
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    allowlistNodes: allowlistNodes
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始，路径包含 Mark、Jonny 或 Zhen 的生成树中看到返回的生成树的 Neo4j Browser 可视化。

apoc.path.spanningTree.alicia allowlist
图 9. 从 Alicia 开始，路径包含 Mark、Jonny 或 Zhen 的生成树

只有 Jonny 可以到达。因此我们可以推断 Mark 和 Zhen 只能通过白名单中未包含的另一个节点才能到达。

黑名单用于从通往可达节点的路径中排除节点。如果希望返回不经过 Joe 即可到达的节点，我们可以通过将 Joe 节点传递给 denylistNodes 参数来实现。

以下查询返回从 Alicia 开始，通过 FOLLOWS 或 KNOWS 关系类型可达的 1 到 3 跳的生成树，其中到达这些节点的路径不经过 Joe
MATCH (p:Person {name: "Alicia"})
MATCH (joe:Person {name: "Joe"})
CALL apoc.path.spanningTree(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    denylistNodes: [joe]
})
YIELD path
RETURN path;

我们可以在从 Alicia 开始，路径不能通过 Joe 的生成树中看到返回的生成树的 Neo4j Browser 可视化。

apoc.path.spanningTree.alicia denylist joe
图 10. 从 Alicia 开始，路径不能通过 Joe 的生成树

关系类型序列

关系类型序列可以通过逗号分隔传递给 relationshipFilter 的值来指定。

例如，如果我们要从 Joe 节点开始，遍历一个由出站方向的 FOLLOWS 关系和任意方向的 KNOWS 关系组成的序列，我们可以指定关系过滤器 FOLLOWS>,KNOWS。

以下查询返回从 Joe 开始，交替遵循 FOLLOWS 和 KNOWS 关系类型可达的节点
MATCH (p:Person {name: "Joe"})
CALL apoc.path.spanningTree(p, {
	relationshipFilter: "FOLLOWS>,KNOWS",
	beginSequenceAtStart: true,
	minLevel: 1,
	maxLevel: 4
})
YIELD path
RETURN path;

我们可以在从 Joe 开始，通过交替的 FOLLOWS 和 KNOWS 关系类型生成的生成树中看到返回的生成树的 Neo4j Browser 可视化。

apoc.path.spanningTree.joe sequence
图 11. 从 Joe 开始，通过交替的 FOLLOWS 和 KNOWS 关系类型生成的生成树
© . All rights reserved.