LIMIT

LIMIT 约束返回的行数。

LIMIT 接受任何求值为正 INTEGER 且不引用节点或关系的表达式。

Neo4j 不保证 LIMIT 生成的结果。唯一能保证特定行顺序的子句是 ORDER BY。

示例图

以下示例使用此图

graph limit clause

要在空的 Neo4j 数据库中重新创建它，请运行以下查询

CREATE
  (andy: Person {name: 'Andy'}),
  (bernard: Person {name: 'Bernard'}),
  (charlotte: Person {name: 'Charlotte'}),
  (david: Person {name: 'David'}),
  (erika: Person {name: 'Erika'}),
  (andy)-[:KNOWS]->(bernard),
  (andy)-[:KNOWS]->(charlotte),
  (andy)-[:KNOWS]->(david),
  (andy)-[:KNOWS]->(erika)

示例

示例 1. 返回行的限定子集

要返回行的限定子集，请使用此语法

查询
MATCH (n)
RETURN n.name
ORDER BY n.name
LIMIT 3

将示例查询限制为 3 行。

表 1. 结果
n.name

"Andy"

"Bernard"

"Charlotte"

行数：3
示例 2. 将表达式与 LIMIT 结合使用以返回行的子集

LIMIT 接受任何求值为正整数的表达式，只要该表达式可以静态计算（即在查询运行前计算）。

查询
MATCH (n)
RETURN n.name
ORDER BY n.name
LIMIT 1 + toInteger(3 * rand())

限制 1 行，再加上随机的 0、1 或 2。因此随机限制为 1、2 或 3 行。

表 2. 结果
n.name

"Andy"

"Bernard"

"Charlotte"

行数：3

LIMIT 和副作用

如果 LIMIT 位于与副作用相同的查询部分，则在查询中使用 LIMIT 不会阻止副作用的发生，例如 CREATE、DELETE 或 SET。

查询
CREATE (n)
RETURN n
LIMIT 0

此查询不返回任何内容，但创建一个节点

表 3. 结果

(空结果)

行数：0
创建的节点：1
查询
MATCH (n {name: 'A'})
SET n.age = 60
RETURN n
LIMIT 0

此查询不返回任何内容，但写入一个属性

表 4. 结果

(空结果)

行数：0
设置的属性：1

如果想限制更新数量，可以使用 WITH 子句来分割查询

查询
MATCH (n)
WITH n ORDER BY n.name LIMIT 1
SET n.locked = true
RETURN n

在一个节点上写入 locked 属性并返回该节点

表 5. 结果
n

{locked:true,name:"Andy",age:60}

行数：1
设置的属性：1

将 LIMIT 用作独立子句

LIMIT 可以作为独立子句使用，也可以与 ORDER BY 或 SKIP/OFFSET 结合使用。

LIMIT 的独立使用
MATCH (n)
LIMIT 2
RETURN collect(n.name) AS names
表 6. 结果
names

["Andy", "Bernard"]

行数：1

以下查询按 name 降序排列所有节点，跳过前两行并将结果限制为两行。然后将结果收集到列表中。

LIMIT 与 ORDER BY 和 SKIP 结合使用
MATCH (n)
ORDER BY n.name DESC
SKIP 2
LIMIT 2
RETURN collect(n.name) AS names
表 7. 结果
names

["David", "Charlotte"]

行数：1