Adamic Adar

此功能在 Aura 图分析无服务器中不可用。

Adamic Adar 是一种根据共享邻居计算节点之间紧密程度的度量。

此功能处于 Alpha 阶段。有关功能分层的更多信息，请参阅API 分层。

历史和解释

Adamic Adar 算法于 2003 年由 Lada Adamic 和 Eytan Adar 提出，用于预测社交网络中的链接。它使用以下公式计算：

其中 N(u) 是与 u 相邻的节点集。

值为 0 表示两个节点不接近，值越高表示节点越接近。

该库包含一个用于计算两个节点之间紧密程度的函数。

语法

以下将运行算法并返回结果：

RETURN gds.alpha.linkprediction.adamicAdar(node1:Node, node2:Node, {
    relationshipQuery:String,
    direction:String
})

表 1. 参数
名称	类型	默认值	可选	描述
`node1`	节点	null	否	一个节点
`node2`	节点	null	否	另一个节点
`relationshipQuery`	字符串	null	是	用于计算 `node1` 和 `node2` 之间相似性的关系类型
`direction`	字符串	BOTH	是	用于计算 `node1` 和 `node2` 之间相似性的关系方向。可能的值为 `OUTGOING`、`INCOMING` 和 `BOTH`。

Adamic Adar 算法示例

以下将创建一个示例图：

CREATE
 (zhen:Person {name: 'Zhen'}),
 (praveena:Person {name: 'Praveena'}),
 (michael:Person {name: 'Michael'}),
 (arya:Person {name: 'Arya'}),
 (karin:Person {name: 'Karin'}),

 (zhen)-[:FRIENDS]->(arya),
 (zhen)-[:FRIENDS]->(praveena),
 (praveena)-[:WORKS_WITH]->(karin),
 (praveena)-[:FRIENDS]->(michael),
 (michael)-[:WORKS_WITH]->(karin),
 (arya)-[:FRIENDS]->(karin)

以下将返回 Michael 和 Karin 的 Adamic Adar 分数：

 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.adamicAdar(p1, p2) AS score

表 2. 结果
`分数`
0.9102392266268373

我们还可以根据特定的关系类型计算一对节点的分数。

以下将仅根据 FRIENDS 关系返回 Michael 和 Karin 的 Adamic Adar 分数：

 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.adamicAdar(p1, p2, {relationshipQuery: 'FRIENDS'}) AS score

表 3. 结果
`分数`
0.0