资源分配

此功能在 Aura 图分析无服务器版中不可用。

资源分配是一种用于根据共享邻居计算节点之间紧密程度的度量。

此功能处于 Alpha 级别。有关功能级别的更多信息，请参阅API 级别。

历史与解释

资源分配算法由周涛、吕琳媛和张翼成于 2009 年提出，作为预测各种网络中链接研究的一部分。它通过以下公式计算：

resource allocation

其中 N(u) 是与 u 相邻的节点集合。

值为 0 表示两个节点不接近，而较高的值表示节点更接近。

该库包含一个计算两个节点之间紧密程度的函数。

语法

以下将运行算法并返回结果
RETURN gds.alpha.linkprediction.resourceAllocation(node1:Node, node2:Node, {
    relationshipQuery:String,
    direction:String
})
表 1. 参数
名称 类型 默认值 可选 描述

node1

节点

null

否

一个节点

node2

节点

null

否

另一个节点

relationshipQuery

字符串

null

是

用于计算 node1 和 node2 之间相似度的关系类型

方向

字符串

BOTH

是

用于计算 node1 和 node2 之间相似度的关系方向。可能的值为 OUTGOING、INCOMING 和 BOTH。

资源分配算法示例

以下将创建一个示例图
CREATE
 (zhen:Person {name: 'Zhen'}),
 (praveena:Person {name: 'Praveena'}),
 (michael:Person {name: 'Michael'}),
 (arya:Person {name: 'Arya'}),
 (karin:Person {name: 'Karin'}),

 (zhen)-[:FRIENDS]->(arya),
 (zhen)-[:FRIENDS]->(praveena),
 (praveena)-[:WORKS_WITH]->(karin),
 (praveena)-[:FRIENDS]->(michael),
 (michael)-[:WORKS_WITH]->(karin),
 (arya)-[:FRIENDS]->(karin)
以下将返回 Michael 和 Karin 的资源分配分数
 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.resourceAllocation(p1, p2) AS score
表 2. 结果
分数

0.3333333333333333

我们还可以根据特定的关系类型计算一对节点的分数。

以下将仅根据 FRIENDS 关系返回 Michael 和 Karin 的资源分配分数
 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.resourceAllocation(p1, p2, {relationshipQuery: "FRIENDS"}) AS score
表 3. 结果
分数

0.0
© . All rights reserved.