Adamic Adar

Adamic Adar 是一种用于计算基于节点共享邻居的节点接近度的指标。

此功能处于 alpha 级别。有关功能级别的更多信息，请参阅 API 级别。

历史和解释

Adamic Adar 算法由 Lada Adamic 和 Eytan Adar 于 2003 年提出，用于预测社交网络中的链接。它使用以下公式计算

其中 N(u) 是与 u 相邻的节点集。

值为 0 表示两个节点不接近，而较高的值表示节点更接近。

该库包含一个函数来计算两个节点之间的接近度。

语法

以下将运行算法并返回结果

RETURN gds.alpha.linkprediction.adamicAdar(node1:Node, node2:Node, {
    relationshipQuery:String,
    direction:String
})

表 1. 参数
名称	类型	默认值	可选	描述
`node1`	节点	null	否	一个节点
`node2`	节点	null	否	另一个节点
`relationshipQuery`	字符串	null	是	用于计算 `node1` 和 `node2` 之间相似度的关系类型
`direction`	字符串	BOTH	是	用于计算 `node1` 和 `node2` 之间相似度的关系方向。可能的值为 `OUTGOING`、`INCOMING` 和 `BOTH`。

Adamic Adar 算法示例

以下将创建一个示例图

CREATE
 (zhen:Person {name: 'Zhen'}),
 (praveena:Person {name: 'Praveena'}),
 (michael:Person {name: 'Michael'}),
 (arya:Person {name: 'Arya'}),
 (karin:Person {name: 'Karin'}),

 (zhen)-[:FRIENDS]->(arya),
 (zhen)-[:FRIENDS]->(praveena),
 (praveena)-[:WORKS_WITH]->(karin),
 (praveena)-[:FRIENDS]->(michael),
 (michael)-[:WORKS_WITH]->(karin),
 (arya)-[:FRIENDS]->(karin)

以下将返回 Michael 和 Karin 的 Adamic Adar 分数

 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.adamicAdar(p1, p2) AS score

表 2. 结果
`score`
0.9102392266268373

我们还可以根据特定关系类型计算一对节点的分数。

以下将返回 Michael 和 Karin 的 Adamic Adar 分数，仅基于 FRIENDS 关系

 MATCH (p1:Person {name: 'Michael'})
 MATCH (p2:Person {name: 'Karin'})
 RETURN gds.alpha.linkprediction.adamicAdar(p1, p2, {relationshipQuery: 'FRIENDS'}) AS score

表 3. 结果
`score`
0.0