GraphGists

癌症药物发现中的竞争情报

使用Ian Robinson的“为可查询性设计”建模方法

1. 应用程序/最终用户目标

作为科学家、投资者、患者、医生、朋友

我想知道哪家公司正在开发治疗癌症的疗法，治疗哪种癌症，目标是什么，以及该疗法处于哪个开发阶段

以便我们了解治疗方案，如果我是患者，可以与医生讨论这些方案，或者与朋友和家人讨论方案，或者选择投资以支持疗法的开发。

2. 领域问题

哪些公司正在开发肺癌疗法，它们叫什么名字？哪些基于抗体的疗法是针对非小细胞肺癌开发的，它们处于哪个开发阶段？哪些公司开发的疗法靶向PDCD1分子？

3. 识别实体

哪些**公司**正在开发针对**肺癌**的**疗法**？哪些基于**抗体**的**疗法**是针对**非小细胞肺癌**开发的，它们处于哪个**开发阶段**？哪些**公司**开发的**疗法**靶向**PDCD1分子**？

  • 公司

  • 治疗分子

  • 疾病

  • 治疗方式

  • 开发阶段

  • 分子靶点

4. 识别实体之间的关系

哪些**公司**正在开发针对**肺癌**的**疗法**？哪些基于**抗体**的**疗法**是针对**非小细胞肺癌**开发的，它们处于哪个**开发阶段**？哪些**公司**开发的**疗法**靶向**PD-1分子**？哪些**公司**正在开发针对**肺腺癌**的**疗法**？

  • 治疗分子 developedByCompany 公司

  • 治疗分子 isIndicatedForDisease 疾病

  • 治疗分子 hasModality 治疗方式

  • 治疗分子 isInHighestDevelopmentStage 开发阶段

  • 治疗分子 inhibits|activates 分子靶点

  • 疾病 typeOfDisease 疾病

  • 治疗方式 typeOfModality 治疗方式

5. 转换为Cypher路径

  • 治疗分子 developedByCompany 公司 →

(:TherapeuticMolecule) - [:developedByCompany] -> (:Company)

  • 治疗分子 isIndicatedForDisease 疾病 →

(:TherapeuticMolecule) - [:isIndicatedForDisease] -> (:Disease)

  • 治疗分子 hasModality 治疗方式 →

(:TherapeuticMolecule) - [:hasModality] -> (:Modality)

  • 治疗分子 isInHighestDevelopmentStage 开发阶段 →

(:TherapeuticMolecule) - [:isInHighestDevelopmentStage] -> (:DevelopmentStage)

  • 治疗分子 inhibitsTargets|activatesTargets 分子靶点 →

(:TherapeuticMolecule) - [:inhibitsTargets|activatesTargets] -> (:MolecularTarget)

  • 疾病 typeOfDisease 疾病 →

(:Disease) - [:typeOfDisease] -> (:Disease)

  • 治疗方式 typeOfModality 治疗方式 →

(:Modality) - [:typeOfModality] -> (:Modality)

合并路径

(:TherapeuticMolecule) - [:developedByCompany] -> (:Company)
(:TherapeuticMolecule) - [:isIndicatedForDisease] -> (:Disease)
(:TherapeuticMolecule) - [:hasModality] -> (:Modality)
(:TherapeuticMolecule) - [:isInHighestDevelopmentStage] -> (:DevelopmentStage)
(:TherapeuticMolecule) - [:inhibitsTargets|activatesTargets] -> (:MolecularTarget)
(:Disease) - [:typeOfDisease] -> (:Disease)
(:Modality) - [:typeOfModality] -> (:Modality)

→

(:TherapeuticMolecule) - [:developedByCompany] -> (:Company)
(:TherapeuticMolecule) - [:isIndicatedForDisease] -> (:Disease) - [:typeOfDisease] -> (:Disease)
(:TherapeuticMolecule) - [:hasModality] -> (:Modality) - [:typeOfModality] -> (:Modality)

候选数据模型

公司和治疗分子

MATCH (c:Company)<-[:developedByCompany]-(t:TherapeuticMolecule)
WHERE c.Name = 'Biomarin Pharmaceuticals'
RETURN c.Name,t.Name

治疗分子和公司表

MATCH (t:TherapeuticMolecule)-[:developedByCompany]->(c:Company)
RETURN t.Name as therapeutic, collect(c.Name) as company
ORDER by therapeutic

治疗分子和公司表

MATCH (t:TherapeuticMolecule)-[:developedByCompany]->(c:Company)
RETURN t,c

公司、治疗分子和疾病

MATCH (c:Company)<-[:developedByCompany]-(t:TherapeuticMolecule)-[:isIndicatedForDisease]->(d:Disease)
RETURN c.Name as Company,t.Name as Therapeutics,collect(d.Name) as Diseases

适用于肺癌的公司和治疗分子

MATCH (c:Company)<-[:developedByCompany]-(t:TherapeuticMolecule)-[:isIndicatedForDisease]->(d:Disease)-[:typeOfDisease*0..2]->(dc:Disease)
WHERE dc.Name = 'Lung Cancer'
RETURN c.Name as Company,t.Name as Therapeutics,collect(d.Name) as Diseases,dc.Name as DiseaseClass

靶向PDCD1的公司和治疗分子

MATCH (c:Company)<-[:developedByCompany]-(t:TherapeuticMolecule)-[:isIndicatedForDisease]->(d:Disease),(t:TherapeuticMolecule)-[:inhibitsTargets]->(mt:MolecularTarget)
WHERE mt.Name = 'PDCD1'
RETURN collect(c.Name) as Company,t.Name as Therapeutics,collect(d.Name) as Diseases,mt.Name as MolecularTarget

针对非小细胞肺癌的公司和治疗分子及其开发阶段

MATCH (c:Company)<-[:developedByCompany]-(t:TherapeuticMolecule)-[:isIndicatedForDisease]->(d:Disease),(t:TherapeuticMolecule)-[:inhibitsTargets]->(mt:MolecularTarget),(t:TherapeuticMolecule)-[:isInHighestDevelopmentStage]->(ds:DevelopmentStage)
WHERE d.Name = 'NSCLC-Non Small Cell Lung Cancer'
RETURN collect(c.Name) as Companies,collect(t.Name) as Therapeutics,d.Name as Disease,collect(mt.Name) as MolecularTargets,ds.Name as Stage
© . All rights reserved.