GraphConnect Europe 2017 时间表图

耶！又到了这一年一度的时候了！我们正在全力准备两年一度的图数据库盛会，也就是 GraphConnect。我们已经为它准备了另一个精彩的会议。整个 Neo4j 团队将全力以赴——当然，我们必须再创建一个时间表图，只是为了好玩而已。

使用 Google 表格作为主要存储库

我当然必须从 GraphConnect 网站的时间表开始，然后将其转换为包含所有数据的 Google 表格。一旦有了它，我就可以使用这个模型非常轻松地添加数据

非常简单——但是，当你能够使其具有交互性并将其加载到 Neo4j 中时，它会变得更加美妙。让我们这样做。让我们将这些数据加载到这个图 Gist 中。

//add the speakers and companies
load csv with headers from
"https://docs.google.com/a/neotechnology.com/spreadsheets/d/1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps/export?format=csv&id=1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps&gid=1504480307" as csv
merge (p:Person {name: csv.name, title: csv.title, bio: csv.bio})
merge (c:Company {name: csv.company})
with csv
match (p:Person {name: csv.name, title: csv.title, bio: csv.bio}), (c:Company {name: csv.company})
merge (p)-[:WORKS_FOR]->(c);

//add the rooms, tracks, floors
load csv with headers from "https://docs.google.com/a/neotechnology.com/spreadsheets/d/1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps/export?format=csv&id=1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps&gid=284108" as csv
merge (f:Floor {name: csv.floor})
merge (r:Room {name: csv.room})-[:LOCATED_ON]->(f)
merge (t:Track {name: csv.track});


//add the timeslots to each day
load csv with headers from "https://docs.google.com/a/neotechnology.com/spreadsheets/d/1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps/export?format=csv&id=1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps&gid=284108" as csv
merge (t1:Time {time: toInt(csv.start)})
merge (t2:Time {time: toInt(csv.end)});

//Connecting the timeslots
match (t:Time)
with t
order by t.time ASC
with collect(t) as times
  foreach (i in range(0,length(times)-2) |
    foreach (t1 in [times[i]] |
      foreach (t2 in [times[i+1]] |
        merge (t1)-[:FOLLOWED_BY]->(t2))));

//add the sessions and connect them up
load csv with headers from "https://docs.google.com/a/neotechnology.com/spreadsheets/d/1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps/export?format=csv&id=1Hu4l5cfnn6efsAvjNq0DmUyW1K5EiyDd7jpo3Ei3Mps&gid=284108" as csv
match (t2:Time {time: toInt(csv.end)}),
(t1:Time {time: toInt(csv.start)}),
(r:Room {name: csv.room}),
(t:Track {name: csv.track}),
(p:Person {name: csv.speaker})
merge (s:Session {title: csv.title})
set s.abstract = csv.abstract
set s.tags = csv.tags
merge (s)<-[:SPEAKS_IN]-(p)
merge (s)-[:IN_ROOM]->(r)
merge (s)-[:STARTS_AT]->(t1)
merge (s)-[:ENDS_AT]->(t2)
merge (s)-[:IN_TRACK]->(t);

//extract the tags
match (s:Session)
with s, [t in split(s.tags,",") | trim(t)] as tags
unwind tags as tag
merge (t:Tag {name: tag})
merge (s)-[:TAGGED_AS]->(t)
remove s.tags;

让我们看看现在有什么

好吧——看起来像一个又大又胖的毛线球。没什么用。所以让我们试着放大一点，并对我们的图运行一个简单的查询：让我们在第一天找到几个会议

match (t:Time)<--(s:Session)--(connections)
return t,s,connections
limit 50

这是图的示例

让我们再做一次查询

match path = allshortestpaths( (p1:Person)-[*]-(p2:Person) )
where p1.name contains "Morgner"
and p2.name contains "Webber"
return path

并显示结果

现在让我们看看一个人物 (Jim Webber，Neo 名人) 和一个组织 (卫报) 之间的链接。

match (c:Company {name:"The Guardian"}), (p:Person {name:"Jim Webber"}),
path = allshortestpaths( (c)-[*]-(p) )
return path

再次显示结果

最后一个为了好玩：让我们看看有多个演讲者的会议

match (s:Session)-[r:SPEAKS_IN]-(p:Person)
with s, collect(p) as person, count(p) as count
where count > 1
return s,person

并显示它

仅仅是开始……

我们可以查看很多其他东西。如果你有兴趣了解更多，请使用下面的控制台进行探索。

希望这个图 Gist 对你来说很有趣，并且我们很快就能再次见面。

这个图 Gist 由 Rik Van Bruggen 创建

此页面是否有帮助？

GraphGists

GraphConnect Europe 2017 时间表图

使用 Google 表格作为主要存储库

仅仅是开始……​

仅仅是开始……