癌症模型的语义链接

此GraphGist提供了一组Cypher查询，旨在使用属性图数据模型将癌症模型描述与元数据连接起来。

癌症'模型'是指构成'模拟'基础的'数学'或'计算'模型。在这种情况下，我们指的是癌症生物学建模，因此也指癌症功能和进展的模拟（即癌症的预测过程）。'模型描述'是模型的抽象，包含元数据以及对模型实现的引用（可能是代码或可执行文件）。模型通常具有一些初始状态，模拟会在该状态中产生一些变化或渐进变化。对于癌症模型，我们可能有一些起始参数和肿瘤的3D模型，运行模拟时，参数会被更新，3D模型也会发生变化，以反映肿瘤生命周期的随时间变化预测。有关癌症生物学入门，请在此处查看免费电子书：https://bookboon.com/en/introduction-to-cancer-biology-ebook

我们相信，在属性图中表示癌症模型集合，有助于创建可查询的系统，通过这些系统，我们可以通过与领域数据的语义链接来探索癌症模型的组合。使用属性图数据模型背后的想法是能够通过领域特定的元数据将不同的癌症模型连接起来，例如单位、计算类型以及生物学术语和分类法类别。

通过这个数据库，我们可以提出以下问题，例如

哪些癌症模型属于同一类别？
哪些癌症模型具有共同的输入和输出参数？
哪些癌症模型是直接或间接连接在一起的？

数据模型

实体

MODEL - 表示一个抽象的模型描述
PARAMETER - 表示一个模型接口参数
CATEGORY - 表示癌症模型分类的元数据
TERM - 表示受控词汇术语的元数据
UNIT - 表示度量单位的元数据
PERSON - 表示一个人
ORGANISATION - 表示一个组织

关系

HAS_INPUT - 将模型与其输入参数连接
HAS_OUTPUT - 将模型与其输出参数连接
HAS_METADATA - 将模型和参数与元数据连接
HAS_CATEGORY - 将类别与其他类别（即子类别）连接
CONTAINS - 将模型与其他子模型连接（以显示模型构成）
SYNONYM_OF_TERM - 将术语与同义术语连接
CREATED_BY - 将模型与其创建者（或作者）连接
CONTRIBUTED_BY - 将模型与模型描述的发布者（即数据库记录）连接

查询控制台

填充图 ^顶部

// Create DB
// TUMOR taxonomy
CREATE (TumorMetadata:Category {name:'Tumor Model Metadata'})
CREATE (Math:Category {name:'Math'})
CREATE (SingleScale:Category {name:'Single-scale'})
CREATE (Multiscale:Category {name:'Multiscale'})
CREATE (Approach:Category {name:'Modeling approach'})
CREATE (Cancer:Category {name:'Cancer'})
CREATE (Homogeneity:Category {name:'Homogeneity'})
CREATE
  (TumorMetadata)-[:HAS_CATEGORY]->(Math),
  (TumorMetadata)-[:HAS_CATEGORY]->(SingleScale),
  (TumorMetadata)-[:HAS_CATEGORY]->(Multiscale),
  (TumorMetadata)-[:HAS_CATEGORY]->(Approach),
  (TumorMetadata)-[:HAS_CATEGORY]->(Cancer),
  (TumorMetadata)-[:HAS_CATEGORY]->(Homogeneity)
CREATE (Discrete:Category {name:'Discrete'})
CREATE (Continuous:Category {name:'Continuous'})
CREATE (Hybrid:Category {name:'Hybrid'})
CREATE
  (Math)-[:HAS_CATEGORY]->(Discrete),
  (Math)-[:HAS_CATEGORY]->(Continuous),
  (Math)-[:HAS_CATEGORY]->(Hybrid)
CREATE (Organ:Category {name:'Organ'})
CREATE (Tissue:Category {name:'Tissue'})
CREATE (Cell:Category {name:'Cell'})
CREATE (Subcellular:Category {name:'Subcellular'})
CREATE (Gene:Category {name:'Gene'})
CREATE
  (SingleScale)-[:HAS_CATEGORY]->(Organ),
  (SingleScale)-[:HAS_CATEGORY]->(Tissue),
  (SingleScale)-[:HAS_CATEGORY]->(Cell),
  (SingleScale)-[:HAS_CATEGORY]->(Subcellular),
  (SingleScale)-[:HAS_CATEGORY]->(Gene)

CREATE (TopDown:Category {name:'Top-down'})
CREATE (BottomUp:Category {name:'Bottom-up'})
CREATE (MiddleOut:Category {name:'Middle-out'})
CREATE
  (Approach)-[:HAS_CATEGORY]->(TopDown),
  (Approach)-[:HAS_CATEGORY]->(BottomUp),
  (Approach)-[:HAS_CATEGORY]->(MiddleOut)
CREATE (Glioma:Category {name:'Glioma'})
CREATE (Nephroblastoma:Category {name:'Nephroblastoma'})
CREATE (Lung:Category {name:'Lung'})
CREATE (Breast:Category {name:'Breast'})
CREATE (Generic:Category {name:'Generic'})
CREATE
  (Cancer)-[:HAS_CATEGORY]->(Glioma),
  (Cancer)-[:HAS_CATEGORY]->(Nephroblastoma),
  (Cancer)-[:HAS_CATEGORY]->(Lung),
  (Cancer)-[:HAS_CATEGORY]->(Breast),
  (Cancer)-[:HAS_CATEGORY]->(Generic)
CREATE (Homogeneous:Category {name:'Homogeneous'})
CREATE (NonHomogeneous:Category {name:'Non-homogeneous'})
CREATE
  (Homogeneity)-[:HAS_CATEGORY]->(Homogeneous),
  (Homogeneity)-[:HAS_CATEGORY]->(NonHomogeneous)
CREATE (TreatmentIncluded:Category {name:'Treatment included'})
CREATE (NoTreatmentIncluded:Category {name:'No treatment included'})
CREATE
  (TumorMetadata)-[:HAS_CATEGORY]->(TreatmentIncluded),
  (TumorMetadata)-[:HAS_CATEGORY]->(NoTreatmentIncluded)

// Units metadata
CREATE (SiBaseUnit:Unit {name:'SI base unit'})
CREATE (Meter:Unit {name:'Meter'})
CREATE (Kilogram:Unit {name:'Kilogram'})
CREATE (Second:Unit {name:'Second'})
CREATE (Ampere:Unit {name:'Ampere'})
CREATE (Kelvin:Unit {name:'Kelvin'})
CREATE (Mole:Unit {name:'Mole'})
CREATE (Candela:Unit {name:'Candela'})
CREATE
  (SiBaseUnit)-[:HAS_CATEGORY]->(Meter),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Kilogram),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Second),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Ampere),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Kelvin),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Mole),
  (SiBaseUnit)-[:HAS_CATEGORY]->(Candela)
CREATE (TumorExtraUnit:Unit {name:'TUMOR extra unit'})
CREATE (Item:Unit {name:'Item'})
CREATE (Gray:Unit {name:'Gray'})
CREATE (Unitless:Unit {name:'Unitless'})
CREATE
  (TumorExtraUnit)-[:HAS_CATEGORY]->(Item),
  (TumorExtraUnit)-[:HAS_CATEGORY]->(Gray),
  (TumorExtraUnit)-[:HAS_CATEGORY]->(Unitless)
CREATE (ConversionFactor:Unit {name:'Conversion factor'})
CREATE (Tera:Unit {name:'Tera'})
CREATE (Giga:Unit {name:'Giga'})
CREATE (Mega:Unit {name:'Mega'})
CREATE (Kilo:Unit {name:'Kilo'})
CREATE (Hecto:Unit {name:'Hecto'})
CREATE (Deca:Unit {name:'Deca'})
CREATE (Deci:Unit {name:'Deci'})
CREATE (Centi:Unit {name:'Centi'})
CREATE (Milli:Unit {name:'Milli'})
CREATE (Micro:Unit {name:'Micro'})
CREATE (Nano:Unit {name:'Nano'})
CREATE (Pico:Unit {name:'Pico'})
CREATE
  (ConversionFactor)-[:HAS_CATEGORY]->(Tera),
  (ConversionFactor)-[:HAS_CATEGORY]->(Giga),
  (ConversionFactor)-[:HAS_CATEGORY]->(Mega),
  (ConversionFactor)-[:HAS_CATEGORY]->(Kilo),
  (ConversionFactor)-[:HAS_CATEGORY]->(Hecto),
  (ConversionFactor)-[:HAS_CATEGORY]->(Deca),
  (ConversionFactor)-[:HAS_CATEGORY]->(Deci),
  (ConversionFactor)-[:HAS_CATEGORY]->(Centi),
  (ConversionFactor)-[:HAS_CATEGORY]->(Milli),
  (ConversionFactor)-[:HAS_CATEGORY]->(Micro),
  (ConversionFactor)-[:HAS_CATEGORY]->(Nano),
  (ConversionFactor)-[:HAS_CATEGORY]->(Pico)
//CLI data types
CREATE
	(CLImetadata:Type { name : 'CLI metadata' }),
	(CLImetadata)-[:HAS_CATEGORY]->(CLIdataType:Type { name :"CLI data type"}),
	(int:Type { name : 'Integer' }),
	(double:Type { name : 'Double precision floating point' }),
	(filename:Type { name :'Filename' }),
	(string:Type { name : 'String' }),
	(CLIdataType)-[:HAS_CATEGORY]->(int),
	(CLIdataType)-[:HAS_CATEGORY]->(double),
	(CLIdataType)-[:HAS_CATEGORY]->(filename),
	(CLIdataType)-[:HAS_CATEGORY]->(string)

// Create Tom and Bill at CBML
CREATE (Tom:Person {URN:'urn:orcid:tumor:0000-0003-2850-3614', fullname:'Thomas S. Deisboeck'})
CREATE (Bill:Person {URN:'urn:tumorml.org:user:000001', fullname:'Zhihui Bill Wang'})
CREATE (CBML:Organisation {URN:'urn:tumorml.org:organisation:000001', fullname:'Complex Biosystems Modeling Laboratory (CBML), Massachusetts General Hospital'})
CREATE
  (Tom)-[:MEMBER_OF]->(CBML),
  (Bill)-[:MEMBER_OF]->(CBML)

// Create EGFR-ERK Pathway
CREATE (EgfrErkPathway:Model {URN:'urn:miriam:tumor:000001', title: 'EGFR-ERK Pathway'})
CREATE (EGF:Parameter {name:'EGF'})
CREATE (CellCycleTime1:Parameter {name:'Cell cycle time'})
CREATE (PLCg:Parameter {name:'PLCg'})
CREATE
  (EgfrErkPathway)-[:HAS_INPUT]->(EGF),
  (EgfrErkPathway)-[:HAS_OUTPUT]->(CellCycleTime1),
  (EgfrErkPathway)-[:HAS_OUTPUT]->(PLCg)
CREATE
  (EgfrErkPathway)-[:CONTRIBUTED_TO_BY]->(Tom),
  (EgfrErkPathway)-[:CREATED_BY]->(Bill),
  (EgfrErkPathway)-[:PUBLISHED_BY]->(CBML)
CREATE
  (EgfrErkPathway)-[:HAS_METADATA]->(Subcellular),
  (EgfrErkPathway)-[:HAS_METADATA]->(Continuous),
  (EgfrErkPathway)-[:HAS_METADATA]->(BottomUp),
  (EgfrErkPathway)-[:HAS_METADATA]->(Homogeneous),
  (EgfrErkPathway)-[:HAS_METADATA]->(NoTreatmentIncluded),
  (EgfrErkPathway)-[:HAS_METADATA]->(Lung)

// Create David and Anthony
CREATE (ImperialCollege:Organisation {URN:'urn:tumorml.org:organisation:000002', name:'Discovery Sciences Group, Imperial College London'})
CREATE (David:Person {URN:'urn:orcid:tumor:0000-0002-2323-6847', name:'David Johnson'})
CREATE 	(Anthony:Person {URN:'urn:tumorml.org:user:000002', name:'Anthony J. Connor'})
CREATE (OxfordUniversity:Organisation {URN:'urn:tumorml.org:organisation:000003', name:'Computational Biology Group, University of Oxford'})

CREATE
	(David)-[:MEMBER_OF]->(ImperialCollege),
	(Anthony)-[:MEMBER_OF]->(OxfordUniversity)

//Create model for VTG Framework
CREATE
	(model3:Model { URN : 'urn:miriam:tumor:000003', title : 'Vascular Tumour Growth Framework'}),
	(model3)-[:HAS_CREATOR]->(Anthony),
	(model3)-[:HAS_PUBLISHER]->(David),
	(model3)-[:HAS_METADATA]->(Continuous),
	(model3)-[:HAS_METADATA]->(BottomUp),
	(model3)-[:HAS_METADATA]->(NonHomogeneous)

//Import term for VEGF from NCIt
CREATE (C1272:Term { term : 'C1272', source : 'NCI Thesaurus' })
CREATE (C1272_term1:Term { term : 'Recombinant Vascular Endothelial Growth Factor' })
CREATE (C1272_term2:Term { term : 'rhuVEGF' })
CREATE (C1272_term3:Term { term : 'vascular endothelial growth factor' })
CREATE (C1272_term4:Term { term : 'Vascular Endothelial Growth Factor' })
CREATE (C1272_term5:Term { term : 'Vascular Permeability Factor' })
CREATE (C1272_term6:Term { term : 'VEGF' })
CREATE (C1272_term7:Term { term : 'VPF' })
CREATE
	(C1272)-[:PREFERRED_TERM]->(C1272_term1),
	(C1272)-[:PREFERRED_TERM]->(C1272_term3),
	(C1272)-[:ABBREVIATION]->(C1272_term2),
	(C1272)-[:ABBREVIATION]->(C1272_term6),
	(C1272)-[:ABBREVIATION]->(C1272_term7),
	(C1272)-[:SYNONYM]->(C1272_term4),
	(C1272)-[:SYNONYM]->(C1272_term5)

//Import term for intracellular from NCIt
CREATE (C28217:Term { term : 'C28217', source : 'NCI Thesaurus' })
CREATE (C28217_term1:Term { term : 'Intracellular' })
CREATE (C28217_term2:Term { term : 'intracellular' })
CREATE
	(C28217)-[:PREFERRED_TERM]->(C28217_term1),
	(C28217)-[:PREFERRED_TERM]->(C28217_term2)

//Import term for extracellular from NCIt
CREATE (C26055:Term { term : 'C26055', source : 'NCI Thesaurus' })
CREATE (C26055_term1:Term { term : 'Extracellular Space' })
CREATE (C26055)-[:PREFERRED_TERM]->(C26055_term1)

//Combine terms into single nodes
CREATE (IntraCellVEGF:Term { term : 'Intracellular VEGF', source : 'User-defined' })
CREATE
   (IntraCellVEGF)-[:HAS_METADATA]->(C1272),
   (IntraCellVEGF)-[:HAS_METADATA]->(C28217)
CREATE (ExtraCellVEGF:Term { term : 'Extracellular VEGF', source : 'User-defined' })
CREATE
   (ExtraCellVEGF)-[:HAS_METADATA]->(C1272),
   (ExtraCellVEGF)-[:HAS_METADATA]->(C26055)

//Create model for Alarcon 2005 Subcellular
CREATE (model4:Model {URN:'urn:miriam:tumor:000004', title:'Alarcon 2005 Subcellular model'})
CREATE
	(model4)-[:HAS_CREATOR]->(Anthony),
	(model4)-[:HAS_PUBLISHER]->(David)
CREATE (Oxygen:Parameter {name:'oxygen'})
CREATE (CellDistribution:Parameter {name:'cell_distribution'})
CREATE (VEGF:Parameter {name:'vegf'})
CREATE (P53:Parameter {name:'p53'})
CREATE (CellCycleTime2:Parameter {name:'cell_cycle_time'})
CREATE (CellState:Parameter {name:'cell_state'})
CREATE
	(model4)-[:HAS_INPUT]->(Oxygen),
	(model4)-[:HAS_INPUT]->(CellDistribution),
	(model4)-[:HAS_OUTPUT]->(VEGF),
	(model4)-[:HAS_OUTPUT]->(P53),
	(model4)-[:HAS_OUTPUT]->(CellCycleTime2),
	(model4)-[:HAS_OUTPUT]->(CellState),
	(model4)-[:HAS_METADATA]->(Continuous),
	(model4)-[:HAS_METADATA]->(BottomUp),
	(model4)-[:HAS_METADATA]->(NonHomogeneous),
	(model4)-[:HAS_METADATA]->(NoTreatmentIncluded),
	(VEGF)-[:HAS_METADATA]->(IntraCellVEGF)

//Create model for Owen 2011 Subcellular model
CREATE (model5:Model {URN:'urn:miriam:tumor:000005', title:'Owen 2011 Subcellular model'})
CREATE
	(model5)-[:HAS_CREATOR]->(Anthony),
	(model5)-[:HAS_PUBLISHER]->(David),
	(model5)-[:HAS_METADATA]->(Continuous),
	(model5)-[:HAS_METADATA]->(BottomUp),
	(model5)-[:HAS_METADATA]->(NonHomogeneous),
	(model5)-[:HAS_METADATA]->(NoTreatmentIncluded)

//Create model for Fixed Duration Subcellular model (Alarcon 2003)
CREATE (model6:Model {URN:'urn:miriam:tumor:000006', title:'Fixed Duration Subcellular model'})
CREATE
	(model6)-[:HAS_CREATOR]->(Anthony),
	(model6)-[:HAS_PUBLISHER]->(David),
	(model6)-[:HAS_METADATA]->(Continuous),
	(model6)-[:HAS_METADATA]->(BottomUp),
	(model6)-[:HAS_METADATA]->(NonHomogeneous),
	(model6)-[:HAS_METADATA]->(NoTreatmentIncluded)

//Create model for VEGF calculator (Alarcon 2005)
CREATE (model7:Model {URN:'urn:miriam:tumor:000007', title:'Alarcon 2005 VEGF Calculator'})
CREATE
	(model7)-[:HAS_CREATOR]->(Anthony),
	(model7)-[:HAS_PUBLISHER]->(David)
CREATE
	(model7)-[:HAS_METADATA]->(Continuous),
	(model7)-[:HAS_METADATA]->(BottomUp),
	(model7)-[:HAS_METADATA]->(NonHomogeneous),
	(model7)-[:HAS_METADATA]->(NoTreatmentIncluded)
CREATE (VEGFin1:Parameter {name:'cellular_vegf'} )
CREATE (VEGFout1:Parameter {name:'extracellular_vegf'} )
CREATE
	(model7)-[:HAS_INPUT]->(VEGFin1),
	(model7)-[:HAS_OUTPUT]->(VEGFout1)
CREATE
	(VEGFin1)-[:HAS_CLIDATATYPE]->(double),
	(VEGFin1)-[:HAS_UNIT]->(Mole),
	(VEGFin1)-[:HAS_FACTOR]->(Nano),
	(VEGFin1)-[:HAS_METADATA]->(IntraCellVEGF)
CREATE
	(VEGFout1)-[:HAS_CLIDATATYPE]->(double),
	(VEGFout1)-[:HAS_UNIT]->(Mole),
	(VEGFout1)-[:HAS_FACTOR]->(Nano),
	(VEGFout1)-[:HAS_METADATA]->(ExtraCellVEGF)

//Create model for VEGF calculator (Alarcon 2006)
CREATE (model8:Model {URN:'urn:miriam:tumor:000008', title:'Alarcon 2006 VEGF Calculator'})
CREATE
	(model8)-[:HAS_CREATOR]->(Anthony),
	(model8)-[:HAS_PUBLISHER]->(David)
CREATE
	(model8)-[:HAS_METADATA]->(Continuous),
	(model8)-[:HAS_METADATA]->(BottomUp),
	(model8)-[:HAS_METADATA]->(NonHomogeneous),
	(model8)-[:HAS_METADATA]->(NoTreatmentIncluded)
CREATE (VEGFin2:Parameter {name:'cellular_vegf'} )
CREATE (VEGFout2:Parameter {name:'extracellular_vegf'} )
CREATE
	(model8)-[:HAS_INPUT]->(VEGFin2),
	(model8)-[:HAS_OUTPUT]->(VEGFout2)
CREATE
	(VEGFin2)-[:HAS_CLIDATATYPE]->(double),
	(VEGFin2)-[:HAS_UNIT]->(Mole),
	(VEGFin2)-[:HAS_FACTOR]->(Nano),
	(VEGFin2)-[:HAS_METADATA]->(IntraCellVEGF)
CREATE
	(VEGFout2)-[:HAS_CLIDATATYPE]->(double),
	(VEGFout2)-[:HAS_UNIT]->(Mole),
	(VEGFout2)-[:HAS_FACTOR]->(Nano),
	(VEGFout2)-[:HAS_METADATA]->(ExtraCellVEGF)

//Create model for VEGF calculator (Owen 2011)
CREATE (model9:Model {URN:'urn:miriam:tumor:000009', title:'Owen 2011 VEGF Calculator'})
CREATE
	(model9)-[:HAS_CREATOR]->(Anthony),
	(model9)-[:HAS_PUBLISHER]->(David)
CREATE
	(model9)-[:HAS_METADATA]->(Continuous),
	(model9)-[:HAS_METADATA]->(BottomUp),
	(model9)-[:HAS_METADATA]->(NonHomogeneous),
	(model8)-[:HAS_METADATA]->(NoTreatmentIncluded)
CREATE (VEGFin3:Parameter {name:'cellular_vegf'} )
CREATE (VEGFout3:Parameter {name:'extracellular_vegf'} )
CREATE
	(model8)-[:HAS_INPUT]->(VEGFin3),
	(model8)-[:HAS_OUTPUT]->(VEGFout3)
CREATE
	(VEGFin3)-[:HAS_CLIDATATYPE]->(double),
	(VEGFin3)-[:HAS_UNIT]->(Mole),
	(VEGFin3)-[:HAS_FACTOR]->(Nano),
	(VEGFin3)-[:HAS_METADATA]->(IntraCellVEGF)
CREATE
	(VEGFout3)-[:HAS_CLIDATATYPE]->(double),
	(VEGFout3)-[:HAS_UNIT]->(Mole),
	(VEGFout3)-[:HAS_FACTOR]->(Nano),
	(VEGFout3)-[:HAS_METADATA]->(ExtraCellVEGF)

//Create model for Metabolic Stimulus Calculation (Alarcon 2005)
CREATE (model10:Model {URN:'urn:miriam:tumor:000010', title:'Alarcon 2005 Metabolic Stimulus Calculation'})
CREATE
	(model10)-[:HAS_CREATOR]->(Anthony),
	(model10)-[:HAS_PUBLISHER]->(David)
CREATE
	(model10)-[:HAS_METADATA]->(Continuous),
	(model10)-[:HAS_METADATA]->(BottomUp),
	(model10)-[:HAS_METADATA]->(NonHomogeneous),
	(model10)-[:HAS_METADATA]->(NoTreatmentIncluded)

//Create model for Angiogenesis Model (Owen 2009)
CREATE (model11:Model {URN:'urn:miriam:tumor:000011', title:'Owen 2009 Angiogenesis Model'})
CREATE
	(model11)-[:HAS_CREATOR]->(Anthony),
	(model11)-[:HAS_PUBLISHER]->(David)
CREATE
	(model11)-[:HAS_METADATA]->(Continuous),
	(model11)-[:HAS_METADATA]->(BottomUp),
	(model11)-[:HAS_METADATA]->(NonHomogeneous),
	(model11)-[:HAS_METADATA]->(NoTreatmentIncluded)


//Create model for Angiogenesis Model (Owen 2011)
CREATE (model12:Model {URN:'urn:miriam:tumor:000012', title:'Owen 2011 Angiogenesis Model'})
CREATE
	(model12)-[:HAS_CREATOR]->(Anthony),
	(model12)-[:HAS_PUBLISHER]->(David)
CREATE
	(model12)-[:HAS_METADATA]->(Continuous),
	(model12)-[:HAS_METADATA]->(BottomUp),
	(model12)-[:HAS_METADATA]->(NonHomogeneous),
	(model12)-[:HAS_METADATA]->(NoTreatmentIncluded)

//Create model for Alarcon 03 Subcellular Model
CREATE (model14:Model {URN:'urn:miriam:tumor:000014', title:'Alarcon 03 Subcellular Model'})
CREATE
	(model14)-[:HAS_CREATOR]->(Anthony),
	(model14)-[:HAS_PUBLISHER]->(David)
CREATE
	(model14)-[:HAS_METADATA]->(Subcellular)

//Create model for Alarcon 03 Cell Proliferation Model
CREATE (model15:Model {URN:'urn:miriam:tumor:000015', title:'Alarcon 03 Cell Proliferation Model'})
CREATE
	(model15)-[:HAS_CREATOR]->(Anthony),
	(model15)-[:HAS_PUBLISHER]->(David)
CREATE
	(model15)-[:HAS_METADATA]->(Cell)

//Create model for Alarcon 03 Oxygen Calculator
CREATE (model16:Model {URN:'urn:miriam:tumor:000016', title:'Alarcon 03  Oxygen Calculator'})
CREATE
	(model16)-[:HAS_CREATOR]->(Anthony),
	(model16)-[:HAS_PUBLISHER]->(David)
CREATE
	(model16)-[:HAS_METADATA]->(Tissue)

//Create model for Alarcon 03 Vascular Structural Adaptation Model
CREATE (model17:Model {URN:'urn:miriam:tumor:000017', title:'Alarcon 03  Vascular Structural Adaptation Model'})
CREATE
	(model17)-[:HAS_CREATOR]->(Anthony),
	(model17)-[:HAS_PUBLISHER]->(David)
CREATE
	(model17)-[:HAS_METADATA]->(Tissue)

//Create model for Alarcon 03 Model
CREATE (model13:Model {URN:'urn:miriam:tumor:000013', title:'Alarcon 03 Model'})
CREATE
	(model13)-[:HAS_CREATOR]->(Anthony),
	(model13)-[:HAS_PUBLISHER]->(David)
CREATE
	(model13)-[:HAS_METADATA]->(Multiscale),
	(model13)-[:CONTAINS]->(model14),
	(model13)-[:CONTAINS]->(model15),
	(model13)-[:CONTAINS]->(model16),
	(model13)-[:CONTAINS]->(model17)

可视化图 ^顶部

下方是使用癌症模型描述测试数据集对整个属性图进行的可视化。要了解更多有关所用癌症模型的信息，请查阅我们的论文《体外癌症模型的语义链接》：https://www.la-press.com/semantically-linking-in-silico-cancer-models-article-a4552

完整的图本身并没有特别大的用处。然而，它为进行更有趣的查询（例如下面的查询）提供了基础。

癌症模型描述

这是模型作为属性图的可视化方式。在这种情况下，这是Z. Wang等人发表于《Simulating non-small cell lung cancer with a multiscale agent-based model, Theor Biol Med Model, 4(1):50+, Dec. 2007》中的 EGFR-ERK 分子通路模型。 https://dx.doi.org/10.1186/1742-4682-4-50

模型具有元数据，例如创建者、贡献者、发布者、模型分类（例如肺癌、均匀肿瘤块、亚细胞尺度）以及输入和输出参数（例如EGF浓度、细胞周期时间）。参数可以链接到在领域图中表示的其他领域元数据。

领域元数据

类别

癌症模型的分类法类别。

MATCH (n:Category)
RETURN collect(n.name) AS Categories

单位

包括SI单位和一些导出单位的数值单位。

MATCH (n:Unit)
RETURN collect(n.name) AS Units

CLI数据类型

命令行界面数据类型，例如字符串、文件名和不同格式的数字。

MATCH (n:Type)
RETURN collect(n.name) AS CLIdatatypes

人员与组织

对模型开发或描述拥有所有权或做出贡献的外部实体。

MATCH (n:Person)-[:MEMBER_OF]-(m:Organisation)
RETURN n.name AS Name, m.name AS Organisation

哪些癌症模型是使用连续数学建模的？ ^顶部

MATCH (n:Model)
WHERE (n)-[:HAS_METADATA]-({ name:'Continuous'})
RETURN n.title AS Model

哪些癌症模型具有共同且兼容的输入和输出参数？ ^顶部

MATCH (n:Model)-[:HAS_INPUT]-(p:Parameter)-[:HAS_METADATA]-(meta:Term)-[:HAS_METADATA]-(q:Parameter)-[:HAS_OUTPUT]-(m:Model)
WHERE n<>m
RETURN DISTINCT m.title AS ModelA, n.title AS ModelB, q.name AS OutputA, p.name AS InputB, meta.term

在多尺度Alarcon 2003模型中，组件模型和相应的尺度是什么？ ^顶部

MATCH (n:Model {URN: 'urn:miriam:tumor:000013'})-[:HAS_METADATA]-(:Category {name: 'Multiscale'}), (m:Model)
MATCH (n)-[:CONTAINS]-(m)
MATCH (m)-[:HAS_METADATA]-(scale:Category)-[:HAS_CATEGORY]-(:Category {name: 'Single-scale'})
RETURN m.title AS ComponentModel, scale.name As Scale

此页面有帮助吗？

GraphGists