“自描述”的 Neo4j 图数据库（第二部分）

CREATE
	(magazine:META:SourceStructureNodes {type: "MAGAZINE", name: "Magazine"}),
	(volume:META:SourceStructureNodes {type: "VOLUME", name: "Volume"}),
	(issue:META:SourceStructureNodes {type: "ISSUE", name: "Issue"}),
	(page:META:SourceStructureNodes {type: "PAGE", name: "Page"})
// And hook them up to reflect their part-subpart relationship...
CREATE volume - [:FROM_NODE] ->
		(:META:SourceStructureRelationships {type: "PART_OF", name: "Part of"})
		- [:TO_NODE] -> magazine
CREATE issue - [:FROM_NODE] ->
		(:META:SourceStructureRelationships {type: "PART_OF", name: "Part of"})
		- [:TO_NODE] -> volume
CREATE page - [:FROM_NODE] ->
		(:META:SourceStructureRelationships {type: "PART_OF", name: "Part of"})
		- [:TO_NODE] -> issue

CREATE
	(fcov:META:SourceStructureNodes {type: "FCOV", name: "Front cover"}),
	(ifcov:META:SourceStructureNodes {type: "IFCOV", name: "Inside front cover"}),
	(bcov:META:SourceStructureNodes {type: "BCOV", name: "Back cover"}),
	(ibcov:META:SourceStructureNodes {type: "IBCOV", name: "Inside back cover"}),
	(masthead:META:SourceStructureNodes {type: "MASTHEAD", name: "Masthead"}),
	(toc:META:SourceStructureNodes {type: "TOC", name: "Table of Contents"}),
	(loa:META:SourceStructureNodes {type: "LOA", name: "List of Advertisers"}),
	(column:META:SourceStructureNodes {type: "COLUMN", name: "Column"}),
	(feature:META:SourceStructureNodes {type: "FEATURE", name: "Feature"}),
	(review:META:SourceStructureNodes {type: "REVIEW", name: "Review"}),
	(top30:META:SourceStructureNodes {type: "TOP30", name: "Top 30 List"}),
	(top10biz:META:SourceStructureNodes {type: "TOP10BIZ", name: "Top 10 Business List"}),
	(top10gam:META:SourceStructureNodes {type: "TOP10GAM", name: "Top 10 Games List"}),
	(ad:META:SourceStructureNodes {type: "AD", name: "Advertisement"})
WITH [fcov, ifcov, bcov, ibcov, masthead, toc, loa, column, feature, review, top30, top10biz, top10gam, ad] as pg_parts
MATCH (page:META:SourceStructureNodes)
WHERE page.type = "PAGE"
FOREACH (pg_part IN pg_parts |
	CREATE pg_part - [:FROM_NODE] ->
		(r:META:SourceStructureRelationships {type: "PART_OF", name: "Part of"})
		- [:TO_NODE] -> page)

CREATE
	(person:META:SourceContentNodes {type: "PERSON", name: "Person"}),
	(company:META:SourceContentNodes {type: "COMPANY", name: "Company"}),
	(product:META:SourceContentNodes {type: "PRODUCT", name: "Product"}),
	(location:META:SourceContentNodes {type: "LOCATION", name: "Location"}),
	(event:META:SourceContentNodes {type: "EVENT", name: "Event"})
WITH [person, company, product, location, event] as content_elements
MATCH (magazine:META:SourceStructureNodes)
WHERE magazine.type = "MAGAZINE"
FOREACH (content_element IN content_elements |
	CREATE magazine - [:FROM_NODE] ->
		(r:META:SourceContentRelationships {type: "IS_ABOUT", name: "is about"})
		- [:TO_NODE] -> content_element)

// Create a root node where the Fact Cloud Property-Builder of the Wizard will hang its generated contributions
// to be picked up by a type-matching naming convention.
CREATE (propertyMapRoot:META:SourceContentPropertymaps {name: "Content Propertymaps"} )
// Again applying the type-->label mapping idea, (:PERSON) nodes in the non-meta data will have a set of properties described by the subgraph anchored in the metamodel at (:META:SourceContentPropertymaps {type: "PERSON"}). Same for (:COMPANY) nodes.
CREATE propertyMapRoot - [:IS_A] -> (personPropertymap:META:SourceContentPropertymaps {type: "PERSON", name: "Person properties"} )
CREATE propertyMapRoot - [:IS_A] -> (companyPropertymap:META:SourceContentPropertymaps {type: "COMPANY", name: "Company properties"} )
CREATE
	personPropertymap - [:HAS_PROPERTY] -> (:META:SourceContentNodeProperties {property: "name", name: "Full name", valueType: "text"}),
	personPropertymap - [:HAS_PROPERTY] -> (:META:SourceContentNodeProperties {property: "age", name: "Age", valueType: "number"}),
	personPropertymap - [:HAS_PROPERTY] -> (phoneNum:META:SourceContentNodeProperties {property: "phone", name: "Phone", valueType: "phoneNumber"}),
	companyPropertymap - [:HAS_PROPERTY] -> (:META:SourceContentNodeProperties {property: "name", name: "Name", valueType: "text"}),
	companyPropertymap - [:HAS_PROPERTY] -> phoneNum

CREATE (propertyMapRoot2:META:SourceStructureNodePropertymaps {name: "Structure Node Propertymaps"} )
CREATE propertyMapRoot2 - [:IS_A] -> (pgPartCommonProperties:META:SourceStructureNodePropertymaps {name: "Page part common properties"})
// If the type property of a Propertymap is a collection, it contains the type values to which the shared map applies.
// NOTE: The wizard will likely generate individual Propertymap nodes pointing to shared/reusable Property nodes. I just
// did not want to bulk this gist with too much code or too many elements drawn in the graph visualizations.
SET pgPartCommonProperties.type = ["FCOV", "IFCOV", "BCOV", "IBCOV", "MASTHEAD", "TOC", "LOA", "COLUMN", "FEATURE", "REVIEW", "TOP30", "TOP10BIZ", "TOP10GAM", "AD"]
CREATE
	pgPartCommonProperties - [:FROM_NODE] ->
		(:META:MetaRelationships {type: "HAS_PROPERTY", name: "Has property"})
		- [:TO_NODE] -> (:META:SourceStructureNodeProperties {property: "origin", name: "Origin (x,y)", valueType: "point"}),
	pgPartCommonProperties - [:FROM_NODE] ->
		(:META:MetaRelationships {type: "HAS_PROPERTY", name: "Has property"})
		- [:TO_NODE] -> (:META:SourceStructureNodeProperties {property: "extent", name: "Extent (w,h)", valueType: "point"}),
	pgPartCommonProperties - [:FROM_NODE] ->
		(:META:MetaRelationships {type: "HAS_PROPERTY", name: "Has property"})
		- [:TO_NODE] -> (:META:SourceStructureNodeProperties {property: "raw_text", name: "Raw text", valueType: "string"}),
	pgPartCommonProperties - [:FROM_NODE] ->
		(:META:MetaRelationships {type: "HAS_PROPERTY", name: "Has property"})
		- [:TO_NODE] -> (:META:SourceStructureNodeProperties {property: "raw_image", name: "Raw image", valueType: "sourcecollection:url"})

CREATE (topXlist_item:META:SourceStructureNodes {type: "TOPX_LIST_ITEM", name: "A Bestseller List Line Item"})
WITH topXlist_item
MATCH (topXlist:META:SourceStructureNodes)
WHERE topXlist.type IN ["TOP30", "TOP10BIZ", "TOP10GAM"]
CREATE topXlist_item - [:FROM_NODE] ->
		(:META:SourceStructureRelationships {type: "PART_OF", name: "Part of"})
		- [:TO_NODE] -> topXlist

CREATE (propertyMapRoot:META:SourceStructureRelationshipsPropertymaps {name: "Structure Relationship Propertymaps"} )
CREATE propertyMapRoot - [:IS_A] -> (:META:SourceStructureRelationshipsPropertymaps {type: "PART_OF", property: "position", name: "Position", valueType: "number"})
CREATE propertyMapRoot - [:IS_A] -> (:META:SourceStructureRelationshipsPropertymaps {type: "PART_OF", property: "rating", name: "Rating", valueType: "number"})

MATCH (item:META:SourceStructureNodes), (product:META:SourceContentNodes),
		(developer:META:SourceContentNodes), (publisher:META:SourceContentNodes)
WHERE item.type = 'TOPX_LIST_ITEM' AND product.type = 'PRODUCT' AND developer.type = 'PERSON' AND publisher.type = 'COMPANY'
CREATE
	// The listing's primary identity is the software:PRODUCT that has earned a place on a bestseller list
	p3 = ((item) - [:FROM_NODE] ->
				(:META:SourceStructureRelationships {type: "ON_LIST", name: "on list"})
				- [:TO_NODE] -> (product)),
	// 'Fact bits' in a standard Softalk bestseller listing include the name of the primary developer:PERSON
	// and the name of the publishing company. These 'fact bits' confirm/create relationships accordingly...
	p4 = ((product) - [:FROM_NODE] ->
				(:META:SourceStructureRelationships {type: "DEVELOPER", name: "developer"})
				- [:TO_NODE] -> (developer)),
	p5 = ((product) - [:FROM_NODE] ->
				(:META:SourceStructureRelationships {type: "PUBLISHER", name: "publisher"})
				- [:TO_NODE] -> (publisher))
RETURN p3, p4, p5